同時使用猛禽一擊及摔絆。
# showtooltip 猛禽一擊
/cast 猛禽一擊
/stopcasting
/cast 摔絆
如果以右鍵點擊或寵物雖存在但已死亡，使用復活寵物；如果寵物不存在，使用召喚寵物；如果寵物存在且在戰鬥中，使用治療寵物；如果寵物存在且不在戰鬥中，使用餵食寵物並使用指定食物。
# showtooltip 治療寵物
/cast [button:2,nocombat] 復活寵物;[target=pet,dead,nocombat] 復活寵物;[nopet] 召喚寵物;[combat] 治療寵物; 餵養寵物
/use [pet,nocombat] 食物名稱
左鍵點幫自己綁繃帶，右鍵點幫指定目標綁繃帶
/use [target=player,button:1] 厚符文布繃帶;[help,button:2] 厚符文布繃帶
自從改版之後，因為巨集的寫法有很大的改變，似乎有不少人哇哇叫的樣子
在此列出一些範例，如果有問題歡迎提出來討論
但是在提出之前，請先看看以下這幾點，這邊先列兩種常常會被問的問題：
一、因為CastSpellByName()跟TargetUnit()這兩個指令被禁止用在巨集之中，所以有關判斷任何目標的體力、魔力、buff、debuff的功能，皆不能與技能作組合，講得白話點，也就是不能再以判斷目標的體力、魔力，或是有沒有中何種buff、debuff，來決定該使用什麼技能。
二、大部分的技能會觸發GCD（共同冷卻），而且不論是否施展成功都會觸發，所以不能將兩個會受到GCD影響的技能放在一起，然後期許因為第一個技能還不能使用而去使用第二技能。舉個簡單的例子，如果把破甲放在復仇的後面，不管復仇是不是可用，都保證破甲絕對用不出來。
如果說你的巨集跟上面兩種之一有關的話
必須要修改成以玩家自己判斷狀況的巨集
若堅持要保有原來的功能…
很對不起，那是無解的，請別提出來了
========================== 廢話到此為止 ==============================
=============== 應該有不少人會直接略過上面直接往下看吧 ===============
通用的巨集：
發動攻擊，此巨集不會因為多點了一下而取消攻擊動作，要取消請愛用ESC。
# showtooltip 攻擊
/startattack
設定一個目標作為『focus』的對象
/focus
/s %t！我正在監視你！
顧名思義，『focus』就是設定用來『監控』一個目標。如此一來，即使目標常常換來換去，依然可以非常迅速地『監控』一個重要的目標，對於控場及治療有著很大的幫助。
使用厚符文布繃帶。若是以右鍵點擊，則為自己的寵物使用；若不是以右鍵點擊，則是為一個友善的目標使用；若沒有友善目標，則是為自己使用。
/use [target=pet,button:2] 厚符文布繃帶;[help] 厚符文布繃帶; [target=player] 厚符文布繃帶
依序使用尋找藥草、尋找礦石，依此輪迴。此巨集只會在沒有進入戰鬥時使用以避免觸發GCD。
亦可將各種職業或種族的追蹤技能追加進去，如尋找寶箱、追蹤野獸等。
/castsequence [nocombat] 尋找藥草, 尋找礦石
使用釣魚，若尚未裝備釣魚竿則裝備釣魚竿。如果以右鍵點擊，則是裝備回指定的武器。
/equip [nobutton:2,noequipped:Fishing Pole] 釣魚竿
/cast [nobutton:2,equipped:Fishing Pole] 釣魚
/equipslot [button:2] 16 主手裝備
/equipslot [button:2] 17 副手裝備
戰士巨集：
依照姿態的不同使用反擊風暴、盾牆或魯莽。
/cast [stance:1] 反擊風暴;[stance:2,equipped:Shields] 盾牆;[stance:3] 魯莽
使用嘲諷，並在使用之前切換為防禦姿態（如果必要的話）。
# showtooltip 嘲諷
/cast [stance:2] 嘲諷; 防禦姿態
其他像壓制、拳擊、繳械等技能也可以照樣修改，注意[stance:1]是戰鬥姿態。[stance:3]是狂暴姿態
# showtooltip 懲戒痛擊
/cast [stance:1] 懲戒痛擊; 戰鬥姿態
# showtooltip 狂暴之怒
/cast [stance:3] 狂暴之怒; 狂暴姿態
在切換至戰鬥姿態以及裝備指定武器之後，使用壓制。
旋風斬也是一樣的格式，這裡就不列了。
# showtooltip 壓制
/equip 爽手武器
/cast [stance:1,equipped:Two-Handed Swords/Two-Handed Maces/Two-Handed Axes/Polearms] 壓制;[nostance:1] 戰鬥姿態
使用挫志怒吼，若是以右鍵點擊則使用雷霆一擊。
# showtooltip 雷霆一擊
/cast [button:2] 雷霆一擊; 挫志怒吼
若進入戰鬥狀態，則使用壓制；否則使用衝鋒。若是以右鍵點擊則同時使用英勇打擊。
# showtooltip 壓制
/cast [combat] 壓制; 衝鋒
/stopcasting [button:2]
/cast [button:2] 英勇打擊
使用致死打擊，若致死打擊尚在冷卻時間內則使用旋風斬。
有點強化致死的話，記得把6改成5。
/castsequence reset=6 致死打擊, 旋風斬
同時使用英勇打擊及破甲攻擊。
由於英勇打擊沒有GCD的問題，所以可以跟其他瞬發技能一起使用
當然，怒氣要足夠～
# showtooltip 破甲攻擊
/cast 英勇打擊
/stopcasting
/cast 破甲攻擊
或者下面這個也是可行的，交替使用二個，只要狂按就好。
# showtooltip 破甲攻擊
/castsequence 英勇打擊, 破甲攻擊
如果有裝備盾而且是在戰鬥或防禦姿態就使用盾擊；否則使用拳擊，並於使用前切換到狂暴姿態（如果有必要的話）。
# showtooltip 拳擊
/cast [stance:1/2,equipped:Shields] 盾擊;[stance:1/2,noequipped:Shields] 狂暴姿態; 拳擊
若尚未進入戰鬥時切換為戰鬥姿態（如果必要的話），並使用衝鋒；若已經進入戰鬥時切換為狂暴姿態（如果必要的話），並使用攔截。
# showtooltip 攔截
/cast [stance:1,nocombat] 衝鋒;[nocombat] 戰鬥姿態; [stance:1/2] 狂暴姿態; 攔截
若『滑鼠所指的目標』為敵對目標，則對該目標使用破甲攻擊；否則對『眼前的目標』使用破甲攻擊。
# showtooltip 破甲攻擊
/cast [target=mouseover,exists,harm] 破甲攻擊; 破甲攻擊
透過這樣的實作就能在不需更換眼前的目標的前提下，對其他目標使用破甲攻擊。由於破甲攻擊沒有傷害的特性，所以即使用在被牽制（變形、媚惑…）的目標上也不會造成牽制失效。
牧師巨集：
使用復活術並通知他人。
# showtooltip 復活術
/script s={"台詞一","台詞二","台詞三","台詞四"};
/script if UnitExists("target") and UnitIsDeadOrGhost("target") then SendChatMessage(s[math.random(getn(s))], "SAY");end;
/cast 復活術
台詞過長可能會發生問題，若出現錯誤訊息時試著縮短台詞或減少台詞種類即可。
使用真言術：韌；若以右鍵點擊則使用堅韌導言。
# showtooltip 堅韌導言
/cast [button:2] 堅韌導言; 真言術：韌
立即停止目前動作並使用沉默；如果目標不是敵對狀態，就對目標的目標使用（目標的目標必須為敵對狀態）。
# showtooltip 沉默
/stopcasting
/cast [harm] 沉默; [target=targettarget,harm] 沉默
對目標使用強效治療術，若目標是敵對狀態則對目標的目標使用強效治療術（目標的目標必須為友善狀態）；若以右鍵點擊則對自己使用強效治療術
# showtooltip 強效治療術
/cast [target=player,button:2] 強效治療術;[help] 強效治療術; [target=targettarget,help] 強效治療術
將『眼前的目標』設定為『監控的目標』並使用束縛不死生物。若以右鍵點擊，則直接對『監控的目標』使用束縛不死生物（若『監控的目標』已死亡或不存在，會自動將『眼前的目標』設定為『監控的目標』）。
透過這樣的實作之後，只需要在第一次進行束縛的時候注視著該目標，第二次之後就不必轉頭去看也能夠直接進行束縛。
# showtooltip 束縛不死生物
/clearfocus [target=focus,dead]
/clearfocus [target=focus,noexists]
/focus [nobutton:2]
/focus [target=focus,noexists,button:2]
/cast [target=focus,button:2] 束縛不死生物; 束縛不死生物
獵人巨集：
使用獵豹守護，如果是以右鍵點擊則使用豹群守護。
# showtooltip 豹群守護
/cast [button:2] 豹群守護; 獵豹守護
使用毒蛇釘刺，如果是以右鍵點擊則使用蝮蛇釘刺，如果是以中鍵點擊則使用毒蠍釘刺。
# showtooltip 毒蛇釘刺
/cast [button:2] 毒蠍釘刺;[button:2] 蝮蛇釘刺; 毒蛇釘刺
使用冰凍陷阱，如果以右鍵點擊則使用冰霜陷阱，如果已經進入了戰鬥中則使用假死。
# showtooltip 冰凍陷阱
/cast [nocombat,button:2] 冰霜陷阱;[nocombat] 冰凍陷阱; 假死
使用假死，若假死尚在冷卻時間內則使用逃脫。
# showtooltip 假死
/castsequence reset=30 假死, 逃脫, 逃脫, 逃脫, 逃脫
對敵對目標使用獵人印記。若是以右鍵點擊，則同時命令寵物攻擊。若是在隊伍中，則通知隊友被標印記的目標為何。
若將「/stopmacro [nogroup]」改成「/stopmacro [nogroup:raid]」，則只有在raid中才會通知隊友。
# showtooltip 獵人印記
/cast [harm] 獵人印記
/stopmacro [noharm]
/petattack [pet,button:2]
/stopmacro [nogroup]
/y 攻擊目標為 %t
同時使用猛禽一擊及摔絆。
# showtooltip 猛禽一擊
/cast 猛禽一擊
/stopcasting
/cast 摔絆
如果以右鍵點擊或寵物雖存在但已死亡，使用復活寵物；如果寵物不存在，使用召喚寵物；如果寵物存在且在戰鬥中，使用治療寵物；如果寵物存在且不在戰鬥中，使用餵食寵物並使用指定食物。
# showtooltip 治療寵物
/cast [button:2,nocombat] 復活寵物;[target=pet,dead,nocombat] 復活寵物;[nopet] 召喚寵物;[combat] 治療寵物; 餵養寵物
/use [pet,nocombat] 食物名稱
其他的職業我不是很熟，可是基本上會用到的格式都跟上面差不多
就不多寫了，如果搞不定再提出來吧。
沒有留言:
張貼留言